// 変数初期設定
TargetID=input("ターゲットのLivedoorID")
NumberUnreadOld=0
Flag=1
PutStr2Log=""
PutLine2Log=""

while Flag=1

// APIを叩く
HtmlSource = GETPAGESOURCE("http://rpc.reader.livedoor.com/notify?user="+TargetID)
HtmlLength = length(HtmlSource)
NumberUnread = copy(HtmlSource,2,HtmlLength-3)

// ユーザーの存在チェック
ifb NumberUnread = -1
	msgbox("そのユーザーは存在しません")
	exitexit
endif

ifb NumberUnread < NumberUnreadOld
	// LDRを利用した
	fukidasi(TargetID+"がLDRを閲覧 "+NumberUnreadOld+"件 → "+NumberUnread+"件",0,0,0,,,,$8888FF,0)
	gettime(0)
	PutStr2Log=G_TIME_YY+"年"+G_TIME_MM+"月"+G_TIME_DD+"日"+G_TIME_HH+"時"+G_TIME_NN+"分"+G_TIME_SS+"秒"
	// ログファイルへ出力
	LogFile=FOPEN("Log.txt",F_READ)
	Log=FGET(LogFile,-2)
	if Log="-1" then Log=""
	FCLOSE(LogFile)
	LogFile=FOPEN("Log.txt",F_WRITE)
	FPUT(LogFile,Log+PutStr2Log)
	FCLOSE(LogFile)
else
	// 利用していない
	ifb PutStr2Log=""
		// 起動後一度も閲覧なし
		fukidasi(TargetID+"を監視中 "+NumberUnread+"件",0,0,0,,,,$FF8888,0)
	else
		// 起動後閲覧済み
		fukidasi(TargetID+"を監視中 "+NumberUnread+"件(最終閲覧 "+PutStr2Log+")",0,0,0,,,,$88FF88,0)
	endif
endif

// 終了
StartTime=gettime(0)
CurTime=gettime(0)
while CurTime<StartTime+10
	CurTime=gettime(0)
	ifb getkeystate(VK_ALT) and getkeystate(VK_L)
		Flag=0
		break
	endif
	sleep(0.1)
wend

// 未読数変数の更新
NumberUnreadOld = NumberUnread

wend

//================================================
// 関数
//================================================

//ウェブページのソース取得
FUNCTION GETPAGESOURCE(PageURL)
	msXMLhttp = CREATEOLEOBJ("Microsoft.XMLhttp")
	msXMLhttp.open("GET", PageURL, 0) //async=false(=0)
	msXMLhttp.send()
	RESULT=msXMLhttp.responseText
FEND